// SPDX-License-Identifier: MIT
pragma solidity 0.8.15;
import "./ERC721A.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";
import "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
contract Metropolis888 is ERC721A, Ownable {
\tusing Strings for uint256;
\tstring private _uriPrefix;
\tstring private _uriSuffix;
\tuint256 public maxSupply;
\tuint256 public presaleSupply;
\tuint256 public maxMintAmountPerAddress;
\tuint256 public maxMintAmountPerAddressForVip;
\tbytes32 private _presaleMerkleRoot;
\tbytes32 private _vipAddressesMerkleRoot;
\tenum SaleState { PAUSED, PRESALE, PUBLIC_SALE }
\tmapping(address => uint256) public helpers;
\tstring private contractMetadataURI;
\tSaleState public saleState;
\tevent SaleStateChanged(SaleState indexed oldSaleState, SaleState indexed newSaleState);
\tevent UriPrefixUpdated(string indexed oldURIprefix, string indexed newURIprefix);
\tevent UriSuffixUpdated(string indexed oldURIsuffix, string indexed newURIsuffix);
\tevent MaxSupplyUpdated(uint256 indexed oldMaxSupply, uint256 indexed newMaxSupply);
\tevent PresaleSupplyUpdated(uint256 indexed oldPresaleSupply, uint256 indexed newPresaleSupply);
\tevent MaxMintAmountPerAddressUpdated(uint256 indexed oldMaxMintAmountPerAddress, uint256 indexed newMaxMintAmountPerAddress);
\tevent MaxMintAmountPerAddressForVipUpdated(uint256 indexed oldMaxMintAmountPerAddressForVip, uint256 indexed newMaxMintAmountPerAddressForVip);
\tevent PresaleMerkleRootUpdated(bytes32 indexed oldPresaleMerkleRoot, bytes32 indexed newPresaleMerkleRoot);
\tevent VipAddressesMerkleRootUpdated(bytes32 indexed oldVipAddressesMerkleRoot, bytes32 indexed newVipAddressesMerkleRoot);
\tconstructor(string memory initUriPrefix, bytes32 initPresaleMerkleRoot, bytes32 initVipAddressesMerkleRoot) ERC721A("Metropolis 888", "M888") {
\t\tmaxSupply = 888;
\t\tpresaleSupply = 888;
\t\tmaxMintAmountPerAddress = 1;
\t\tmaxMintAmountPerAddressForVip = 2;
\t\t_uriPrefix = initUriPrefix;
\t\t_uriSuffix = ".json";
\t\t_presaleMerkleRoot = initPresaleMerkleRoot;
\t\t_vipAddressesMerkleRoot = initVipAddressesMerkleRoot;
\t\tsaleState = SaleState.PAUSED;
\t\tcontractMetadataURI = "ipfs://QmPBi8rbrYSpsasFe81C5hdccJiwx9ARBjeBrBb7BzLDv9/metadata.json";
\t}
\tfunction mint(uint256 amount, bytes32[] calldata vipMerkleProof) external payable {
\t\trequire(tx.origin == _msgSender(), "Metropolis 888: contract denied");
\t\trequire(saleState == SaleState.PUBLIC_SALE, "Metropolis 888: minting is not in public sale");
\t\trequire(amount > 0 && _numberMinted(_msgSender()) + amount <= _maxMintAmount(_msgSender(), vipMerkleProof), "Metropolis 888: invalid mint amount");
\t\trequire(_totalMinted() + amount <= maxSupply, "Metropolis 888: max token supply exceeded");
\t\t_safeMint(_msgSender(), amount);
\t}
\tfunction presaleMint(uint256 amount, bytes32[] calldata vipMerkleProof, bytes32[] calldata presaleMerkleProof) external payable {
\t\trequire(tx.origin == _msgSender(), "Metropolis 888: contract denied");
\t\trequire(saleState == SaleState.PRESALE, "Metropolis 888: minting is not in presale");
\t\trequire(amount > 0 && _numberMinted(_msgSender()) + amount <= _maxMintAmount(_msgSender(), vipMerkleProof), "Metropolis 888: invalid mint amount");
\t\trequire(_merkleProof(_msgSender(), presaleMerkleProof, _presaleMerkleRoot), "Metropolis 888: invalid merkle proof");
\t\tuint256 newSupply = _totalMinted() + amount;
\t\trequire(newSupply <= presaleSupply, "Metropolis 888: presale token supply exceeded");
\t\t_safeMint(_msgSender(), amount);
\t}
\tfunction helperMint() external payable {
\t\trequire(tx.origin == _msgSender(), "Metropolis 888: contract denied");
\t\trequire(saleState != SaleState.PAUSED, "Metropolis 888: minting is paused");
\t\tuint256 amount = helpers[msg.sender];
\t\trequire(_totalMinted() + amount <= maxSupply, "Metropolis 888: max token supply exceeded");
\t\thelpers[msg.sender] = 0;
\t\t_safeMint(_msgSender(), amount);
\t}
\tfunction contractURI() public view returns (string memory) {
    return contractMetadataURI;
  }
\tfunction setContractMetadataURI(string memory _contractMetadataURI) external onlyOwner {
\t\tcontractMetadataURI = _contractMetadataURI;
\t}
\tfunction addHelper(address _address, uint256 _amount) external onlyOwner {
        helpers[_address] = _amount;
    }
\tfunction addMultipleHelpers(address[] calldata _addresses, uint256[] calldata _amounts) external onlyOwner {
        require(_addresses.length <= 333,"too many addresses");
\t\trequire(_addresses.length == _amounts.length, "array sizes must match");
        for (uint256 i = 0; i < _addresses.length; i++) {
            helpers[_addresses[i]] = _amounts[i];
        }
    }
\t function removeHelper(address _address) external onlyOwner {
        helpers[_address] = 0;
    }
\t\tfunction isHelper(address _address) public view returns(uint256) {
        return helpers[_address];
    }
\tfunction setSaleState(SaleState newSaleState) external onlyOwner {
\t\temit SaleStateChanged(saleState, newSaleState);
\t\tsaleState = newSaleState;
\t}
\tfunction tokenURI(uint256 tokenId) public view override returns(string memory) {
\t\tif (!_exists(tokenId)) revert URIQueryForNonexistentToken();
\t\tstring memory baseURI = _baseURI();
\t\treturn bytes(baseURI).length != 0 ? string(abi.encodePacked(baseURI, tokenId.toString(), _uriSuffix)) : "";
\t}
\tfunction setUriPrefix(string memory newPrefix) external onlyOwner {
\t\temit UriPrefixUpdated(_uriPrefix, newPrefix);
\t\t_uriPrefix = newPrefix;
\t}
\tfunction setUriSuffix(string memory newSuffix) external onlyOwner {
\t\temit UriSuffixUpdated(_uriSuffix, newSuffix);
\t\t_uriSuffix = newSuffix;
\t}
\tfunction setMaxSupply(uint256 newMaxSupply) external onlyOwner {
\t\trequire(newMaxSupply > _totalMinted() && newMaxSupply > presaleSupply, "Metropolis 888: invalid amount");
\t\temit MaxSupplyUpdated(maxSupply, newMaxSupply);
\t\tmaxSupply = newMaxSupply;
\t}
\tfunction setPresaleSupply(uint256 newPresaleSupply) external onlyOwner {
\t\trequire(newPresaleSupply > _totalMinted() && newPresaleSupply < maxSupply, "Metropolis 888: invalid amount");
\t\temit PresaleSupplyUpdated(presaleSupply, newPresaleSupply);
\t\tpresaleSupply = newPresaleSupply;
\t}
\tfunction setMaxMintAmountPerAddress(uint256 newMaxMintAmountPerAddress) external onlyOwner {
\t\temit MaxMintAmountPerAddressUpdated(maxMintAmountPerAddress, newMaxMintAmountPerAddress);
\t\tmaxMintAmountPerAddress = newMaxMintAmountPerAddress;
\t}
\tfunction setMaxMintAmountPerAddressForVip(uint256 newMaxMintAmountPerAddressForVip) external onlyOwner {
\t\temit MaxMintAmountPerAddressForVipUpdated(maxMintAmountPerAddressForVip, newMaxMintAmountPerAddressForVip);
\t\tmaxMintAmountPerAddressForVip = newMaxMintAmountPerAddressForVip;
\t}
\tfunction setPresaleMerkleRoot(bytes32 newPresaleMerkleRoot) external onlyOwner {
\t\temit PresaleMerkleRootUpdated(_presaleMerkleRoot, newPresaleMerkleRoot);
\t\t_presaleMerkleRoot = newPresaleMerkleRoot;
\t}
\tfunction setVipAddressesMerkleRoot(bytes32 newVipAddressesMerkleRoot) external onlyOwner {
\t\temit VipAddressesMerkleRootUpdated(_vipAddressesMerkleRoot, newVipAddressesMerkleRoot);
\t\t_vipAddressesMerkleRoot = newVipAddressesMerkleRoot;
\t}
\tfunction _baseURI() internal view override returns(string memory) {
\t\treturn _uriPrefix;
\t}
\tfunction _startTokenId() internal pure override returns(uint256) {
\t\treturn 1;
\t}
\tfunction _maxMintAmount(address account, bytes32[] calldata merkleProof) internal view returns(uint256) {
\t\tbool isVip = _merkleProof(account, merkleProof, _vipAddressesMerkleRoot);
\t\treturn isVip ? maxMintAmountPerAddressForVip : maxMintAmountPerAddress;
\t}
\tfunction _merkleProof(address account, bytes32[] calldata merkleProof, bytes32 merkleRoot) internal pure returns(bool) {
\t\tbytes32 leaf = keccak256(abi.encodePacked(account));
\t\tbool verified = MerkleProof.verify(merkleProof, merkleRoot, leaf);
\t\treturn verified;
\t}
}
// SPDX-License-Identifier: MIT
// Creator: Chiru Labs
pragma solidity ^0.8.4;
import '@openzeppelin/contracts/token/ERC721/IERC721.sol';
import '@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol';
import '@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol';
import '@openzeppelin/contracts/utils/Address.sol';
import '@openzeppelin/contracts/utils/Context.sol';
import '@openzeppelin/contracts/utils/Strings.sol';
import '@openzeppelin/contracts/utils/introspection/ERC165.sol';
error ApprovalCallerNotOwnerNorApproved();
error ApprovalQueryForNonexistentToken();
error ApproveToCaller();
error ApprovalToCurrentOwner();
error BalanceQueryForZeroAddress();
error MintToZeroAddress();
error MintZeroQuantity();
error OwnerQueryForNonexistentToken();
error TransferCallerNotOwnerNorApproved();
error TransferFromIncorrectOwner();
error TransferToNonERC721ReceiverImplementer();
error TransferToZeroAddress();
error URIQueryForNonexistentToken();
/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension. Built to optimize for lower gas during batch mints.
 *
 * Assumes serials are sequentially minted starting at _startTokenId() (defaults to 0, e.g. 0, 1, 2, 3..).
 *
 * Assumes that an owner cannot have more than 2**64 - 1 (max value of uint64) of supply.
 *
 * Assumes that the maximum token id cannot exceed 2**256 - 1 (max value of uint256).
 */
contract ERC721A is Context, ERC165, IERC721, IERC721Metadata {
\tusing Address for address;
\tusing Strings for uint256;
\t// Compiler will pack this into a single 256bit word.
\tstruct TokenOwnership {
\t\t// The address of the owner.
\t\taddress addr;
\t\t// Keeps track of the start time of ownership with minimal overhead for tokenomics.
\t\tuint64 startTimestamp;
\t\t// Whether the token has been burned.
\t\tbool burned;
\t}
\t// Compiler will pack this into a single 256bit word.
\tstruct AddressData {
\t\t// Realistically, 2**64-1 is more than enough.
\t\tuint64 balance;
\t\t// Keeps track of mint count with minimal overhead for tokenomics.
\t\tuint64 numberMinted;
\t\t// Keeps track of burn count with minimal overhead for tokenomics.
\t\tuint64 numberBurned;
\t\t// For miscellaneous variable(s) pertaining to the address
\t\t// (e.g. number of whitelist mint slots used).
\t\t// If there are multiple variables, please pack them into a uint64.
\t\tuint64 aux;
\t}
\t// The tokenId of the next token to be minted.
\tuint256 internal _currentIndex;
\t// The number of tokens burned.
\tuint256 internal _burnCounter;
\t// Token name
\tstring private _name;
\t// Token symbol
\tstring private _symbol;
\t// Mapping from token ID to ownership details
\t// An empty struct value does not necessarily mean the token is unowned. See _ownershipOf implementation for details.
\tmapping(uint256 => TokenOwnership) internal _ownerships;
\t// Mapping owner address to address data
\tmapping(address => AddressData) private _addressData;
\t// Mapping from token ID to approved address
\tmapping(uint256 => address) private _tokenApprovals;
\t// Mapping from owner to operator approvals
\tmapping(address => mapping(address => bool)) private _operatorApprovals;
\tconstructor(string memory name_, string memory symbol_) {
\t\t_name = name_;
\t\t_symbol = symbol_;
\t\t_currentIndex = _startTokenId();
\t}
\t/**
\t * To change the starting tokenId, please override this function.
\t */
\tfunction _startTokenId() internal view virtual returns (uint256) {
\t\treturn 0;
\t}
\t/**
\t * @dev Burned tokens are calculated here, use _totalMinted() if you want to count just minted tokens.
\t */
\tfunction totalSupply() public view returns (uint256) {
\t\t// Counter underflow is impossible as _burnCounter cannot be incremented
\t\t// more than _currentIndex - _startTokenId() times
\t\tunchecked {
\t\t\treturn _currentIndex - _burnCounter - _startTokenId();
\t\t}
\t}
\t/**
\t * Returns the total amount of tokens minted in the contract.
\t */
\tfunction _totalMinted() internal view returns (uint256) {
\t\t// Counter underflow is impossible as _currentIndex does not decrement,
\t\t// and it is initialized to _startTokenId()
\t\tunchecked {
\t\t\treturn _currentIndex - _startTokenId();
\t\t}
\t}
\t/**
\t * @dev See {IERC165-supportsInterface}.
\t */
\tfunction supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
\t\treturn
\t\t\tinterfaceId == type(IERC721).interfaceId ||
\t\t\tinterfaceId == type(IERC721Metadata).interfaceId ||
\t\t\tsuper.supportsInterface(interfaceId);
\t}
\t/**
\t * @dev See {IERC721-balanceOf}.
\t */
\tfunction balanceOf(address owner) public view override returns (uint256) {
\t\tif (owner == address(0)) revert BalanceQueryForZeroAddress();
\t\treturn uint256(_addressData[owner].balance);
\t}
\t/**
\t * Returns the number of tokens minted by `owner`.
\t */
\tfunction _numberMinted(address owner) internal view returns (uint256) {
\t\treturn uint256(_addressData[owner].numberMinted);
\t}
\t/**
\t * Returns the number of tokens burned by or on behalf of `owner`.
\t */
\tfunction _numberBurned(address owner) internal view returns (uint256) {
\t\treturn uint256(_addressData[owner].numberBurned);
\t}
\t/**
\t * Returns the auxillary data for `owner`. (e.g. number of whitelist mint slots used).
\t */
\tfunction _getAux(address owner) internal view returns (uint64) {
\t\treturn _addressData[owner].aux;
\t}
\t/**
\t * Sets the auxillary data for `owner`. (e.g. number of whitelist mint slots used).
\t * If there are multiple variables, please pack them into a uint64.
\t */
\tfunction _setAux(address owner, uint64 aux) internal {
\t\t_addressData[owner].aux = aux;
\t}
\t/**
\t * Gas spent here starts off proportional to the maximum mint batch size.
\t * It gradually moves to O(1) as tokens get transferred around in the collection over time.
\t */
\tfunction _ownershipOf(uint256 tokenId) internal view returns (TokenOwnership memory) {
\t\tuint256 curr = tokenId;
\t\tunchecked {
\t\t\tif (_startTokenId() <= curr && curr < _currentIndex) {
\t\t\t\tTokenOwnership memory ownership = _ownerships[curr];
\t\t\t\tif (!ownership.burned) {
\t\t\t\t\tif (ownership.addr != address(0)) {
\t\t\t\t\t\treturn ownership;
\t\t\t\t\t}
\t\t\t\t\t// Invariant:
\t\t\t\t\t// There will always be an ownership that has an address and is not burned
\t\t\t\t\t// before an ownership that does not have an address and is not burned.
\t\t\t\t\t// Hence, curr will not underflow.
\t\t\t\t\twhile (true) {
\t\t\t\t\t\tcurr--;
\t\t\t\t\t\townership = _ownerships[curr];
\t\t\t\t\t\tif (ownership.addr != address(0)) {
\t\t\t\t\t\t\treturn ownership;
\t\t\t\t\t\t}
\t\t\t\t\t}
\t\t\t\t}
\t\t\t}
\t\t}
\t\trevert OwnerQueryForNonexistentToken();
\t}
\t/**
\t * @dev See {IERC721-ownerOf}.
\t */
\tfunction ownerOf(uint256 tokenId) public view override returns (address) {
\t\treturn _ownershipOf(tokenId).addr;
\t}
\t/**
\t * @dev See {IERC721Metadata-name}.
\t */
\tfunction name() public view virtual override returns (string memory) {
\t\treturn _name;
\t}
\t/**
\t * @dev See {IERC721Metadata-symbol}.
\t */
\tfunction symbol() public view virtual override returns (string memory) {
\t\treturn _symbol;
\t}
\t/**
\t * @dev See {IERC721Metadata-tokenURI}.
\t */
\tfunction tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
\t\tif (!_exists(tokenId)) revert URIQueryForNonexistentToken();
\t\tstring memory baseURI = _baseURI();
\t\treturn bytes(baseURI).length != 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : '';
\t}
\t/**
\t * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
\t * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
\t * by default, can be overriden in child contracts.
\t */
\tfunction _baseURI() internal view virtual returns (string memory) {
\t\treturn '';
\t}
\t/**
\t * @dev See {IERC721-approve}.
\t */
\tfunction approve(address to, uint256 tokenId) public override {
\t\taddress owner = ERC721A.ownerOf(tokenId);
\t\tif (to == owner) revert ApprovalToCurrentOwner();
\t\tif (_msgSender() != owner && !isApprovedForAll(owner, _msgSender())) {
\t\t\trevert ApprovalCallerNotOwnerNorApproved();
\t\t}
\t\t_approve(to, tokenId, owner);
\t}
\t/**
\t * @dev See {IERC721-getApproved}.
\t */
\tfunction getApproved(uint256 tokenId) public view override returns (address) {
\t\tif (!_exists(tokenId)) revert ApprovalQueryForNonexistentToken();
\t\treturn _tokenApprovals[tokenId];
\t}
\t/**
\t * @dev See {IERC721-setApprovalForAll}.
\t */
\tfunction setApprovalForAll(address operator, bool approved) public virtual override {
\t\tif (operator == _msgSender()) revert ApproveToCaller();
\t\t_operatorApprovals[_msgSender()][operator] = approved;
\t\temit ApprovalForAll(_msgSender(), operator, approved);
\t}
\t/**
\t * @dev See {IERC721-isApprovedForAll}.
\t */
\tfunction isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
\t\treturn _operatorApprovals[owner][operator];
\t}
\t/**
\t * @dev See {IERC721-transferFrom}.
\t */
\tfunction transferFrom(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId
\t) public virtual override {
\t\t_transfer(from, to, tokenId);
\t}
\t/**
\t * @dev See {IERC721-safeTransferFrom}.
\t */
\tfunction safeTransferFrom(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId
\t) public virtual override {
\t\tsafeTransferFrom(from, to, tokenId, '');
\t}
\t/**
\t * @dev See {IERC721-safeTransferFrom}.
\t */
\tfunction safeTransferFrom(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId,
\t\tbytes memory _data
\t) public virtual override {
\t\t_transfer(from, to, tokenId);
\t\tif (to.isContract() && !_checkContractOnERC721Received(from, to, tokenId, _data)) {
\t\t\trevert TransferToNonERC721ReceiverImplementer();
\t\t}
\t}
\t/**
\t * @dev Returns whether `tokenId` exists.
\t *
\t * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
\t *
\t * Tokens start existing when they are minted (`_mint`),
\t */
\tfunction _exists(uint256 tokenId) internal view returns (bool) {
\t\treturn _startTokenId() <= tokenId && tokenId < _currentIndex && !_ownerships[tokenId].burned;
\t}
\tfunction _safeMint(address to, uint256 quantity) internal {
\t\t_safeMint(to, quantity, '');
\t}
\t/**
\t * @dev Safely mints `quantity` tokens and transfers them to `to`.
\t *
\t * Requirements:
\t *
\t * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called for each safe transfer.
\t * - `quantity` must be greater than 0.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _safeMint(
\t\taddress to,
\t\tuint256 quantity,
\t\tbytes memory _data
\t) internal {
\t\t_mint(to, quantity, _data, true);
\t}
\t/**
\t * @dev Mints `quantity` tokens and transfers them to `to`.
\t *
\t * Requirements:
\t *
\t * - `to` cannot be the zero address.
\t * - `quantity` must be greater than 0.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _mint(
\t\taddress to,
\t\tuint256 quantity,
\t\tbytes memory _data,
\t\tbool safe
\t) internal {
\t\tuint256 startTokenId = _currentIndex;
\t\tif (to == address(0)) revert MintToZeroAddress();
\t\tif (quantity == 0) revert MintZeroQuantity();
\t\t_beforeTokenTransfers(address(0), to, startTokenId, quantity);
\t\t// Overflows are incredibly unrealistic.
\t\t// balance or numberMinted overflow if current value of either + quantity > 1.8e19 (2**64) - 1
\t\t// updatedIndex overflows if _currentIndex + quantity > 1.2e77 (2**256) - 1
\t\tunchecked {
\t\t\t_addressData[to].balance += uint64(quantity);
\t\t\t_addressData[to].numberMinted += uint64(quantity);
\t\t\t_ownerships[startTokenId].addr = to;
\t\t\t_ownerships[startTokenId].startTimestamp = uint64(block.timestamp);
\t\t\tuint256 updatedIndex = startTokenId;
\t\t\tuint256 end = updatedIndex + quantity;
\t\t\tif (safe && to.isContract()) {
\t\t\t\tdo {
\t\t\t\t\temit Transfer(address(0), to, updatedIndex);
\t\t\t\t\tif (!_checkContractOnERC721Received(address(0), to, updatedIndex++, _data)) {
\t\t\t\t\t\trevert TransferToNonERC721ReceiverImplementer();
\t\t\t\t\t}
\t\t\t\t} while (updatedIndex != end);
\t\t\t\t// Reentrancy protection
\t\t\t\tif (_currentIndex != startTokenId) revert();
\t\t\t} else {
\t\t\t\tdo {
\t\t\t\t\temit Transfer(address(0), to, updatedIndex++);
\t\t\t\t} while (updatedIndex != end);
\t\t\t}
\t\t\t_currentIndex = updatedIndex;
\t\t}
\t\t_afterTokenTransfers(address(0), to, startTokenId, quantity);
\t}
\t/**
\t * @dev Transfers `tokenId` from `from` to `to`.
\t *
\t * Requirements:
\t *
\t * - `to` cannot be the zero address.
\t * - `tokenId` token must be owned by `from`.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _transfer(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId
\t) private {
\t\tTokenOwnership memory prevOwnership = _ownershipOf(tokenId);
\t\tif (prevOwnership.addr != from) revert TransferFromIncorrectOwner();
\t\tbool isApprovedOrOwner = (_msgSender() == from ||
\t\t\tisApprovedForAll(from, _msgSender()) ||
\t\t\tgetApproved(tokenId) == _msgSender());
\t\tif (!isApprovedOrOwner) revert TransferCallerNotOwnerNorApproved();
\t\tif (to == address(0)) revert TransferToZeroAddress();
\t\t_beforeTokenTransfers(from, to, tokenId, 1);
\t\t// Clear approvals from the previous owner
\t\t_approve(address(0), tokenId, from);
\t\t// Underflow of the sender's balance is impossible because we check for
\t\t// ownership above and the recipient's balance can't realistically overflow.
\t\t// Counter overflow is incredibly unrealistic as tokenId would have to be 2**256.
\t\tunchecked {
\t\t\t_addressData[from].balance -= 1;
\t\t\t_addressData[to].balance += 1;
\t\t\tTokenOwnership storage currSlot = _ownerships[tokenId];
\t\t\tcurrSlot.addr = to;
\t\t\tcurrSlot.startTimestamp = uint64(block.timestamp);
\t\t\t// If the ownership slot of tokenId+1 is not explicitly set, that means the transfer initiator owns it.
\t\t\t// Set the slot of tokenId+1 explicitly in storage to maintain correctness for ownerOf(tokenId+1) calls.
\t\t\tuint256 nextTokenId = tokenId + 1;
\t\t\tTokenOwnership storage nextSlot = _ownerships[nextTokenId];
\t\t\tif (nextSlot.addr == address(0)) {
\t\t\t\t// This will suffice for checking _exists(nextTokenId),
\t\t\t\t// as a burned slot cannot contain the zero address.
\t\t\t\tif (nextTokenId != _currentIndex) {
\t\t\t\t\tnextSlot.addr = from;
\t\t\t\t\tnextSlot.startTimestamp = prevOwnership.startTimestamp;
\t\t\t\t}
\t\t\t}
\t\t}
\t\temit Transfer(from, to, tokenId);
\t\t_afterTokenTransfers(from, to, tokenId, 1);
\t}
\t/**
\t * @dev This is equivalent to _burn(tokenId, false)
\t */
\tfunction _burn(uint256 tokenId) internal virtual {
\t\t_burn(tokenId, false);
\t}
\t/**
\t * @dev Destroys `tokenId`.
\t * The approval is cleared when the token is burned.
\t *
\t * Requirements:
\t *
\t * - `tokenId` must exist.
\t *
\t * Emits a {Transfer} event.
\t */
\tfunction _burn(uint256 tokenId, bool approvalCheck) internal virtual {
\t\tTokenOwnership memory prevOwnership = _ownershipOf(tokenId);
\t\taddress from = prevOwnership.addr;
\t\tif (approvalCheck) {
\t\t\tbool isApprovedOrOwner = (_msgSender() == from ||
\t\t\t\tisApprovedForAll(from, _msgSender()) ||
\t\t\t\tgetApproved(tokenId) == _msgSender());
\t\t\tif (!isApprovedOrOwner) revert TransferCallerNotOwnerNorApproved();
\t\t}
\t\t_beforeTokenTransfers(from, address(0), tokenId, 1);
\t\t// Clear approvals from the previous owner
\t\t_approve(address(0), tokenId, from);
\t\t// Underflow of the sender's balance is impossible because we check for
\t\t// ownership above and the recipient's balance can't realistically overflow.
\t\t// Counter overflow is incredibly unrealistic as tokenId would have to be 2**256.
\t\tunchecked {
\t\t\tAddressData storage addressData = _addressData[from];
\t\t\taddressData.balance -= 1;
\t\t\taddressData.numberBurned += 1;
\t\t\t// Keep track of who burned the token, and the timestamp of burning.
\t\t\tTokenOwnership storage currSlot = _ownerships[tokenId];
\t\t\tcurrSlot.addr = from;
\t\t\tcurrSlot.startTimestamp = uint64(block.timestamp);
\t\t\tcurrSlot.burned = true;
\t\t\t// If the ownership slot of tokenId+1 is not explicitly set, that means the burn initiator owns it.
\t\t\t// Set the slot of tokenId+1 explicitly in storage to maintain correctness for ownerOf(tokenId+1) calls.
\t\t\tuint256 nextTokenId = tokenId + 1;
\t\t\tTokenOwnership storage nextSlot = _ownerships[nextTokenId];
\t\t\tif (nextSlot.addr == address(0)) {
\t\t\t\t// This will suffice for checking _exists(nextTokenId),
\t\t\t\t// as a burned slot cannot contain the zero address.
\t\t\t\tif (nextTokenId != _currentIndex) {
\t\t\t\t\tnextSlot.addr = from;
\t\t\t\t\tnextSlot.startTimestamp = prevOwnership.startTimestamp;
\t\t\t\t}
\t\t\t}
\t\t}
\t\temit Transfer(from, address(0), tokenId);
\t\t_afterTokenTransfers(from, address(0), tokenId, 1);
\t\t// Overflow not possible, as _burnCounter cannot be exceed _currentIndex times.
\t\tunchecked {
\t\t\t_burnCounter++;
\t\t}
\t}
\t/**
\t * @dev Approve `to` to operate on `tokenId`
\t *
\t * Emits a {Approval} event.
\t */
\tfunction _approve(
\t\taddress to,
\t\tuint256 tokenId,
\t\taddress owner
\t) private {
\t\t_tokenApprovals[tokenId] = to;
\t\temit Approval(owner, to, tokenId);
\t}
\t/**
\t * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target contract.
\t *
\t * @param from address representing the previous owner of the given token ID
\t * @param to target address that will receive the tokens
\t * @param tokenId uint256 ID of the token to be transferred
\t * @param _data bytes optional data to send along with the call
\t * @return bool whether the call correctly returned the expected magic value
\t */
\tfunction _checkContractOnERC721Received(
\t\taddress from,
\t\taddress to,
\t\tuint256 tokenId,
\t\tbytes memory _data
\t) private returns (bool) {
\t\ttry IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
\t\t\treturn retval == IERC721Receiver(to).onERC721Received.selector;
\t\t} catch (bytes memory reason) {
\t\t\tif (reason.length == 0) {
\t\t\t\trevert TransferToNonERC721ReceiverImplementer();
\t\t\t} else {
\t\t\t\tassembly {
\t\t\t\t\trevert(add(32, reason), mload(reason))
\t\t\t\t}
\t\t\t}
\t\t}
\t}
\t/**
\t * @dev Hook that is called before a set of serially-ordered token ids are about to be transferred. This includes minting.
\t * And also called before burning one token.
\t *
\t * startTokenId - the first token id to be transferred
\t * quantity - the amount to be transferred
\t *
\t * Calling conditions:
\t *
\t * - When `from` and `to` are both non-zero, `from`'s `tokenId` will be
\t * transferred to `to`.
\t * - When `from` is zero, `tokenId` will be minted for `to`.
\t * - When `to` is zero, `tokenId` will be burned by `from`.
\t * - `from` and `to` are never both zero.
\t */
\tfunction _beforeTokenTransfers(
\t\taddress from,
\t\taddress to,
\t\tuint256 startTokenId,
\t\tuint256 quantity
\t) internal virtual {}
\t/**
\t * @dev Hook that is called after a set of serially-ordered token ids have been transferred. This includes
\t * minting.
\t * And also called after one token has been burned.
\t *
\t * startTokenId - the first token id to be transferred
\t * quantity - the amount to be transferred
\t *
\t * Calling conditions:
\t *
\t * - When `from` and `to` are both non-zero, `from`'s `tokenId` has been
\t * transferred to `to`.
\t * - When `from` is zero, `tokenId` has been minted for `to`.
\t * - When `to` is zero, `tokenId` has been burned by `from`.
\t * - `from` and `to` are never both zero.
\t */
\tfunction _afterTokenTransfers(
\t\taddress from,
\t\taddress to,
\t\tuint256 startTokenId,
\t\tuint256 quantity
\t) internal virtual {}
}// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Strings.sol)
pragma solidity ^0.8.0;
/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;
    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol
        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }
    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)
pragma solidity ^0.8.0;
import "../utils/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }
    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }
    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }
    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }
    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/cryptography/MerkleProof.sol)
pragma solidity ^0.8.0;
/**
 * @dev These functions deal with verification of Merkle Tree proofs.
 *
 * The proofs can be generated using the JavaScript library
 * https://github.com/miguelmota/merkletreejs[merkletreejs].
 * Note: the hashing algorithm should be keccak256 and pair sorting should be enabled.
 *
 * See `test/utils/cryptography/MerkleProof.test.js` for some examples.
 *
 * WARNING: You should avoid using leaf values that are 64 bytes long prior to
 * hashing, or use a hash function other than keccak256 for hashing leaves.
 * This is because the concatenation of a sorted pair of internal nodes in
 * the merkle tree could be reinterpreted as a leaf value.
 */
library MerkleProof {
    /**
     * @dev Returns true if a `leaf` can be proved to be a part of a Merkle tree
     * defined by `root`. For this, a `proof` must be provided, containing
     * sibling hashes on the branch from the leaf to the root of the tree. Each
     * pair of leaves and each pair of pre-images are assumed to be sorted.
     */
    function verify(
        bytes32[] memory proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProof(proof, leaf) == root;
    }
    /**
     * @dev Calldata version of {verify}
     *
     * _Available since v4.7._
     */
    function verifyCalldata(
        bytes32[] calldata proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProofCalldata(proof, leaf) == root;
    }
    /**
     * @dev Returns the rebuilt hash obtained by traversing a Merkle tree up
     * from `leaf` using `proof`. A `proof` is valid if and only if the rebuilt
     * hash matches the root of the tree. When processing the proof, the pairs
     * of leafs & pre-images are assumed to be sorted.
     *
     * _Available since v4.4._
     */
    function processProof(bytes32[] memory proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            computedHash = _hashPair(computedHash, proof[i]);
        }
        return computedHash;
    }
    /**
     * @dev Calldata version of {processProof}
     *
     * _Available since v4.7._
     */
    function processProofCalldata(bytes32[] calldata proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            computedHash = _hashPair(computedHash, proof[i]);
        }
        return computedHash;
    }
    /**
     * @dev Returns true if the `leaves` can be proved to be a part of a Merkle tree defined by
     * `root`, according to `proof` and `proofFlags` as described in {processMultiProof}.
     *
     * _Available since v4.7._
     */
    function multiProofVerify(
        bytes32[] memory proof,
        bool[] memory proofFlags,
        bytes32 root,
        bytes32[] memory leaves
    ) internal pure returns (bool) {
        return processMultiProof(proof, proofFlags, leaves) == root;
    }
    /**
     * @dev Calldata version of {multiProofVerify}
     *
     * _Available since v4.7._
     */
    function multiProofVerifyCalldata(
        bytes32[] calldata proof,
        bool[] calldata proofFlags,
        bytes32 root,
        bytes32[] memory leaves
    ) internal pure returns (bool) {
        return processMultiProofCalldata(proof, proofFlags, leaves) == root;
    }
    /**
     * @dev Returns the root of a tree reconstructed from `leaves` and the sibling nodes in `proof`,
     * consuming from one or the other at each step according to the instructions given by
     * `proofFlags`.
     *
     * _Available since v4.7._
     */
    function processMultiProof(
        bytes32[] memory proof,
        bool[] memory proofFlags,
        bytes32[] memory leaves
    ) internal pure returns (bytes32 merkleRoot) {
        // This function rebuild the root hash by traversing the tree up from the leaves. The root is rebuilt by
        // consuming and producing values on a queue. The queue starts with the `leaves` array, then goes onto the
        // `hashes` array. At the end of the process, the last hash in the `hashes` array should contain the root of
        // the merkle tree.
        uint256 leavesLen = leaves.length;
        uint256 totalHashes = proofFlags.length;
        // Check proof validity.
        require(leavesLen + proof.length - 1 == totalHashes, "MerkleProof: invalid multiproof");
        // The xxxPos values are "pointers" to the next value to consume in each array. All accesses are done using
        // `xxx[xxxPos++]`, which return the current value and increment the pointer, thus mimicking a queue's "pop".
        bytes32[] memory hashes = new bytes32[](totalHashes);
        uint256 leafPos = 0;
        uint256 hashPos = 0;
        uint256 proofPos = 0;
        // At each step, we compute the next hash using two values:
        // - a value from the "main queue". If not all leaves have been consumed, we get the next leaf, otherwise we
        //   get the next hash.
        // - depending on the flag, either another value for the "main queue" (merging branches) or an element from the
        //   `proof` array.
        for (uint256 i = 0; i < totalHashes; i++) {
            bytes32 a = leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++];
            bytes32 b = proofFlags[i] ? leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++] : proof[proofPos++];
            hashes[i] = _hashPair(a, b);
        }
        if (totalHashes > 0) {
            return hashes[totalHashes - 1];
        } else if (leavesLen > 0) {
            return leaves[0];
        } else {
            return proof[0];
        }
    }
    /**
     * @dev Calldata version of {processMultiProof}
     *
     * _Available since v4.7._
     */
    function processMultiProofCalldata(
        bytes32[] calldata proof,
        bool[] calldata proofFlags,
        bytes32[] memory leaves
    ) internal pure returns (bytes32 merkleRoot) {
        // This function rebuild the root hash by traversing the tree up from the leaves. The root is rebuilt by
        // consuming and producing values on a queue. The queue starts with the `leaves` array, then goes onto the
        // `hashes` array. At the end of the process, the last hash in the `hashes` array should contain the root of
        // the merkle tree.
        uint256 leavesLen = leaves.length;
        uint256 totalHashes = proofFlags.length;
        // Check proof validity.
        require(leavesLen + proof.length - 1 == totalHashes, "MerkleProof: invalid multiproof");
        // The xxxPos values are "pointers" to the next value to consume in each array. All accesses are done using
        // `xxx[xxxPos++]`, which return the current value and increment the pointer, thus mimicking a queue's "pop".
        bytes32[] memory hashes = new bytes32[](totalHashes);
        uint256 leafPos = 0;
        uint256 hashPos = 0;
        uint256 proofPos = 0;
        // At each step, we compute the next hash using two values:
        // - a value from the "main queue". If not all leaves have been consumed, we get the next leaf, otherwise we
        //   get the next hash.
        // - depending on the flag, either another value for the "main queue" (merging branches) or an element from the
        //   `proof` array.
        for (uint256 i = 0; i < totalHashes; i++) {
            bytes32 a = leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++];
            bytes32 b = proofFlags[i] ? leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++] : proof[proofPos++];
            hashes[i] = _hashPair(a, b);
        }
        if (totalHashes > 0) {
            return hashes[totalHashes - 1];
        } else if (leavesLen > 0) {
            return leaves[0];
        } else {
            return proof[0];
        }
    }
    function _hashPair(bytes32 a, bytes32 b) private pure returns (bytes32) {
        return a < b ? _efficientHash(a, b) : _efficientHash(b, a);
    }
    function _efficientHash(bytes32 a, bytes32 b) private pure returns (bytes32 value) {
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, a)
            mstore(0x20, b)
            value := keccak256(0x00, 0x40)
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC1155/IERC1155.sol)
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);
    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );
    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);
    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);
    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);
    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] calldata accounts, uint256[] calldata ids)
        external
        view
        returns (uint256[] memory);
    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;
    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);
    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes calldata data
    ) external;
    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata amounts,
        bytes calldata data
    ) external;
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC721/IERC721.sol)
pragma solidity ^0.8.0;
import "../../utils/introspection/IERC165.sol";
/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);
    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);
    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);
    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);
    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);
    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;
    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;
    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;
    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;
    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);
    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)
pragma solidity ^0.8.0;
/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC721.sol";
/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);
    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);
    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.
        return account.code.length > 0;
    }
    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");
        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }
    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }
    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }
    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }
    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                /// @solidity memory-safe-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)
pragma solidity ^0.8.0;
import "./IERC165.sol";
/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)
pragma solidity ^0.8.0;
/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}