ETH Price: $3,890.49 (+3.34%)

Transaction Decoder

Block:
7579856 at Apr-16-2019 03:51:17 PM +UTC
Transaction Fee:
0.000210792 ETH $0.82
Gas Used:
52,698 Gas / 4 Gwei

Emitted Events:

93 LineAxis.Transfer( from=[Sender] 0x80a770ed037ee684c7bfd11a7a564bf483cec535, to=[Receiver] EtherDelta, value=600000000000 )
94 EtherDelta.Deposit( token=LineAxis, user=[Sender] 0x80a770ed037ee684c7bfd11a7a564bf483cec535, amount=600000000000, balance=600000000000 )

Account State Difference:

  Address   Before After State Difference Code
0x80a770eD...483ceC535
0.00835602 Eth
Nonce: 11
0.008145228 Eth
Nonce: 12
0.000210792
0x8d12A197...2A5CC6819
(EtherDelta 2)
(Ethermine)
321.421525457386422012 Eth321.421736249386422012 Eth0.000210792
0xF0c5831E...e2f007f28

Execution Trace

EtherDelta.depositToken( token=0xF0c5831EC3Da15f3696B4DAd8B21c7Ce2f007f28, amount=600000000000 )
  • LineAxis.transferFrom( from=0x80a770eD037EE684c7bFd11A7A564Bf483ceC535, to=0x8d12A197cB00D4747a1fe03395095ce2A5CC6819, value=600000000000 )
    File 1 of 2: EtherDelta
    pragma solidity ^0.4.9;
    
    contract SafeMath {
      function safeMul(uint a, uint b) internal returns (uint) {
        uint c = a * b;
        assert(a == 0 || c / a == b);
        return c;
      }
    
      function safeSub(uint a, uint b) internal returns (uint) {
        assert(b <= a);
        return a - b;
      }
    
      function safeAdd(uint a, uint b) internal returns (uint) {
        uint c = a + b;
        assert(c>=a && c>=b);
        return c;
      }
    
      function assert(bool assertion) internal {
        if (!assertion) throw;
      }
    }
    
    contract Token {
      /// @return total amount of tokens
      function totalSupply() constant returns (uint256 supply) {}
    
      /// @param _owner The address from which the balance will be retrieved
      /// @return The balance
      function balanceOf(address _owner) constant returns (uint256 balance) {}
    
      /// @notice send `_value` token to `_to` from `msg.sender`
      /// @param _to The address of the recipient
      /// @param _value The amount of token to be transferred
      /// @return Whether the transfer was successful or not
      function transfer(address _to, uint256 _value) returns (bool success) {}
    
      /// @notice send `_value` token to `_to` from `_from` on the condition it is approved by `_from`
      /// @param _from The address of the sender
      /// @param _to The address of the recipient
      /// @param _value The amount of token to be transferred
      /// @return Whether the transfer was successful or not
      function transferFrom(address _from, address _to, uint256 _value) returns (bool success) {}
    
      /// @notice `msg.sender` approves `_addr` to spend `_value` tokens
      /// @param _spender The address of the account able to transfer the tokens
      /// @param _value The amount of wei to be approved for transfer
      /// @return Whether the approval was successful or not
      function approve(address _spender, uint256 _value) returns (bool success) {}
    
      /// @param _owner The address of the account owning tokens
      /// @param _spender The address of the account able to transfer the tokens
      /// @return Amount of remaining tokens allowed to spent
      function allowance(address _owner, address _spender) constant returns (uint256 remaining) {}
    
      event Transfer(address indexed _from, address indexed _to, uint256 _value);
      event Approval(address indexed _owner, address indexed _spender, uint256 _value);
    
      uint public decimals;
      string public name;
    }
    
    contract StandardToken is Token {
    
      function transfer(address _to, uint256 _value) returns (bool success) {
        //Default assumes totalSupply can't be over max (2^256 - 1).
        //If your token leaves out totalSupply and can issue more tokens as time goes on, you need to check if it doesn't wrap.
        //Replace the if with this one instead.
        if (balances[msg.sender] >= _value && balances[_to] + _value > balances[_to]) {
        //if (balances[msg.sender] >= _value && _value > 0) {
          balances[msg.sender] -= _value;
          balances[_to] += _value;
          Transfer(msg.sender, _to, _value);
          return true;
        } else { return false; }
      }
    
      function transferFrom(address _from, address _to, uint256 _value) returns (bool success) {
        //same as above. Replace this line with the following if you want to protect against wrapping uints.
        if (balances[_from] >= _value && allowed[_from][msg.sender] >= _value && balances[_to] + _value > balances[_to]) {
        //if (balances[_from] >= _value && allowed[_from][msg.sender] >= _value && _value > 0) {
          balances[_to] += _value;
          balances[_from] -= _value;
          allowed[_from][msg.sender] -= _value;
          Transfer(_from, _to, _value);
          return true;
        } else { return false; }
      }
    
      function balanceOf(address _owner) constant returns (uint256 balance) {
        return balances[_owner];
      }
    
      function approve(address _spender, uint256 _value) returns (bool success) {
        allowed[msg.sender][_spender] = _value;
        Approval(msg.sender, _spender, _value);
        return true;
      }
    
      function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
        return allowed[_owner][_spender];
      }
    
      mapping(address => uint256) balances;
    
      mapping (address => mapping (address => uint256)) allowed;
    
      uint256 public totalSupply;
    }
    
    contract ReserveToken is StandardToken, SafeMath {
      address public minter;
      function ReserveToken() {
        minter = msg.sender;
      }
      function create(address account, uint amount) {
        if (msg.sender != minter) throw;
        balances[account] = safeAdd(balances[account], amount);
        totalSupply = safeAdd(totalSupply, amount);
      }
      function destroy(address account, uint amount) {
        if (msg.sender != minter) throw;
        if (balances[account] < amount) throw;
        balances[account] = safeSub(balances[account], amount);
        totalSupply = safeSub(totalSupply, amount);
      }
    }
    
    contract AccountLevels {
      //given a user, returns an account level
      //0 = regular user (pays take fee and make fee)
      //1 = market maker silver (pays take fee, no make fee, gets rebate)
      //2 = market maker gold (pays take fee, no make fee, gets entire counterparty's take fee as rebate)
      function accountLevel(address user) constant returns(uint) {}
    }
    
    contract AccountLevelsTest is AccountLevels {
      mapping (address => uint) public accountLevels;
    
      function setAccountLevel(address user, uint level) {
        accountLevels[user] = level;
      }
    
      function accountLevel(address user) constant returns(uint) {
        return accountLevels[user];
      }
    }
    
    contract EtherDelta is SafeMath {
      address public admin; //the admin address
      address public feeAccount; //the account that will receive fees
      address public accountLevelsAddr; //the address of the AccountLevels contract
      uint public feeMake; //percentage times (1 ether)
      uint public feeTake; //percentage times (1 ether)
      uint public feeRebate; //percentage times (1 ether)
      mapping (address => mapping (address => uint)) public tokens; //mapping of token addresses to mapping of account balances (token=0 means Ether)
      mapping (address => mapping (bytes32 => bool)) public orders; //mapping of user accounts to mapping of order hashes to booleans (true = submitted by user, equivalent to offchain signature)
      mapping (address => mapping (bytes32 => uint)) public orderFills; //mapping of user accounts to mapping of order hashes to uints (amount of order that has been filled)
    
      event Order(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, address user);
      event Cancel(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, address user, uint8 v, bytes32 r, bytes32 s);
      event Trade(address tokenGet, uint amountGet, address tokenGive, uint amountGive, address get, address give);
      event Deposit(address token, address user, uint amount, uint balance);
      event Withdraw(address token, address user, uint amount, uint balance);
    
      function EtherDelta(address admin_, address feeAccount_, address accountLevelsAddr_, uint feeMake_, uint feeTake_, uint feeRebate_) {
        admin = admin_;
        feeAccount = feeAccount_;
        accountLevelsAddr = accountLevelsAddr_;
        feeMake = feeMake_;
        feeTake = feeTake_;
        feeRebate = feeRebate_;
      }
    
      function() {
        throw;
      }
    
      function changeAdmin(address admin_) {
        if (msg.sender != admin) throw;
        admin = admin_;
      }
    
      function changeAccountLevelsAddr(address accountLevelsAddr_) {
        if (msg.sender != admin) throw;
        accountLevelsAddr = accountLevelsAddr_;
      }
    
      function changeFeeAccount(address feeAccount_) {
        if (msg.sender != admin) throw;
        feeAccount = feeAccount_;
      }
    
      function changeFeeMake(uint feeMake_) {
        if (msg.sender != admin) throw;
        if (feeMake_ > feeMake) throw;
        feeMake = feeMake_;
      }
    
      function changeFeeTake(uint feeTake_) {
        if (msg.sender != admin) throw;
        if (feeTake_ > feeTake || feeTake_ < feeRebate) throw;
        feeTake = feeTake_;
      }
    
      function changeFeeRebate(uint feeRebate_) {
        if (msg.sender != admin) throw;
        if (feeRebate_ < feeRebate || feeRebate_ > feeTake) throw;
        feeRebate = feeRebate_;
      }
    
      function deposit() payable {
        tokens[0][msg.sender] = safeAdd(tokens[0][msg.sender], msg.value);
        Deposit(0, msg.sender, msg.value, tokens[0][msg.sender]);
      }
    
      function withdraw(uint amount) {
        if (tokens[0][msg.sender] < amount) throw;
        tokens[0][msg.sender] = safeSub(tokens[0][msg.sender], amount);
        if (!msg.sender.call.value(amount)()) throw;
        Withdraw(0, msg.sender, amount, tokens[0][msg.sender]);
      }
    
      function depositToken(address token, uint amount) {
        //remember to call Token(address).approve(this, amount) or this contract will not be able to do the transfer on your behalf.
        if (token==0) throw;
        if (!Token(token).transferFrom(msg.sender, this, amount)) throw;
        tokens[token][msg.sender] = safeAdd(tokens[token][msg.sender], amount);
        Deposit(token, msg.sender, amount, tokens[token][msg.sender]);
      }
    
      function withdrawToken(address token, uint amount) {
        if (token==0) throw;
        if (tokens[token][msg.sender] < amount) throw;
        tokens[token][msg.sender] = safeSub(tokens[token][msg.sender], amount);
        if (!Token(token).transfer(msg.sender, amount)) throw;
        Withdraw(token, msg.sender, amount, tokens[token][msg.sender]);
      }
    
      function balanceOf(address token, address user) constant returns (uint) {
        return tokens[token][user];
      }
    
      function order(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce) {
        bytes32 hash = sha256(this, tokenGet, amountGet, tokenGive, amountGive, expires, nonce);
        orders[msg.sender][hash] = true;
        Order(tokenGet, amountGet, tokenGive, amountGive, expires, nonce, msg.sender);
      }
    
      function trade(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, address user, uint8 v, bytes32 r, bytes32 s, uint amount) {
        //amount is in amountGet terms
        bytes32 hash = sha256(this, tokenGet, amountGet, tokenGive, amountGive, expires, nonce);
        if (!(
          (orders[user][hash] || ecrecover(sha3("\x19Ethereum Signed Message:\n32", hash),v,r,s) == user) &&
          block.number <= expires &&
          safeAdd(orderFills[user][hash], amount) <= amountGet
        )) throw;
        tradeBalances(tokenGet, amountGet, tokenGive, amountGive, user, amount);
        orderFills[user][hash] = safeAdd(orderFills[user][hash], amount);
        Trade(tokenGet, amount, tokenGive, amountGive * amount / amountGet, user, msg.sender);
      }
    
      function tradeBalances(address tokenGet, uint amountGet, address tokenGive, uint amountGive, address user, uint amount) private {
        uint feeMakeXfer = safeMul(amount, feeMake) / (1 ether);
        uint feeTakeXfer = safeMul(amount, feeTake) / (1 ether);
        uint feeRebateXfer = 0;
        if (accountLevelsAddr != 0x0) {
          uint accountLevel = AccountLevels(accountLevelsAddr).accountLevel(user);
          if (accountLevel==1) feeRebateXfer = safeMul(amount, feeRebate) / (1 ether);
          if (accountLevel==2) feeRebateXfer = feeTakeXfer;
        }
        tokens[tokenGet][msg.sender] = safeSub(tokens[tokenGet][msg.sender], safeAdd(amount, feeTakeXfer));
        tokens[tokenGet][user] = safeAdd(tokens[tokenGet][user], safeSub(safeAdd(amount, feeRebateXfer), feeMakeXfer));
        tokens[tokenGet][feeAccount] = safeAdd(tokens[tokenGet][feeAccount], safeSub(safeAdd(feeMakeXfer, feeTakeXfer), feeRebateXfer));
        tokens[tokenGive][user] = safeSub(tokens[tokenGive][user], safeMul(amountGive, amount) / amountGet);
        tokens[tokenGive][msg.sender] = safeAdd(tokens[tokenGive][msg.sender], safeMul(amountGive, amount) / amountGet);
      }
    
      function testTrade(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, address user, uint8 v, bytes32 r, bytes32 s, uint amount, address sender) constant returns(bool) {
        if (!(
          tokens[tokenGet][sender] >= amount &&
          availableVolume(tokenGet, amountGet, tokenGive, amountGive, expires, nonce, user, v, r, s) >= amount
        )) return false;
        return true;
      }
    
      function availableVolume(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, address user, uint8 v, bytes32 r, bytes32 s) constant returns(uint) {
        bytes32 hash = sha256(this, tokenGet, amountGet, tokenGive, amountGive, expires, nonce);
        if (!(
          (orders[user][hash] || ecrecover(sha3("\x19Ethereum Signed Message:\n32", hash),v,r,s) == user) &&
          block.number <= expires
        )) return 0;
        uint available1 = safeSub(amountGet, orderFills[user][hash]);
        uint available2 = safeMul(tokens[tokenGive][user], amountGet) / amountGive;
        if (available1<available2) return available1;
        return available2;
      }
    
      function amountFilled(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, address user, uint8 v, bytes32 r, bytes32 s) constant returns(uint) {
        bytes32 hash = sha256(this, tokenGet, amountGet, tokenGive, amountGive, expires, nonce);
        return orderFills[user][hash];
      }
    
      function cancelOrder(address tokenGet, uint amountGet, address tokenGive, uint amountGive, uint expires, uint nonce, uint8 v, bytes32 r, bytes32 s) {
        bytes32 hash = sha256(this, tokenGet, amountGet, tokenGive, amountGive, expires, nonce);
        if (!(orders[msg.sender][hash] || ecrecover(sha3("\x19Ethereum Signed Message:\n32", hash),v,r,s) == msg.sender)) throw;
        orderFills[msg.sender][hash] = amountGet;
        Cancel(tokenGet, amountGet, tokenGive, amountGive, expires, nonce, msg.sender, v, r, s);
      }
    }

    File 2 of 2: LineAxis
    pragma solidity ^0.4.24;
    
    
    
    /**
     * @title Ownable
     * @dev The Ownable contract has an owner address, and provides basic authorization control
     * functions, this simplifies the implementation of "user permissions".
     */
    
    contract Owned {
        address private _owner;
        address private _newOwner;
    
        event TransferredOwner(
            address indexed previousOwner,
            address indexed newOwner
        );
    
      /**
       * @dev The Ownable constructor sets the original `owner` of the contract to the sender
       * account.
       */
        constructor() internal {
            _owner = msg.sender;
            emit TransferredOwner(address(0), _owner);
        }
    
      /**
       * @return the address of the owner.
       */
    
        function owner() public view returns(address) {
            return _owner;
        }
    
      /**
       * @dev Throws if called by any account other than the owner.
       */
        modifier onlyOwner() {
            require(isOwner(), "Access is denied");
            _;
        }
    
      /**
       * @return true if `msg.sender` is the owner of the contract.
       */
        function isOwner() public view returns(bool) {
            return msg.sender == _owner;
        }
    
      /**
       * @dev Allows the current owner to relinquish control of the contract.
       * @notice Renouncing to ownership will leave the contract without an owner.
       * It will not be possible to call the functions with the `onlyOwner`
       * modifier anymore.
       */
        function renounceOwner() public onlyOwner {
            emit TransferredOwner(_owner, address(0));
            _owner = address(0);
        }
    
      /**
       * @dev Allows the current owner to transfer control of the contract to a newOwner.
       * @param newOwner The address to transfer ownership to.
       */
        function transferOwner(address newOwner) public onlyOwner {
            require(newOwner != address(0), "Empty address");
            _newOwner = newOwner;
        }
    
    
        function cancelOwner() public onlyOwner {
            _newOwner = address(0);
        }
    
        function confirmOwner() public {
            require(msg.sender == _newOwner, "Access is denied");
            emit TransferredOwner(_owner, _newOwner);
            _owner = _newOwner;
        }
    }
    
    
    
    
    /**
     * @title Standard ERC20 token
     *
     * @dev Implementation of the basic standard token.
     * https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20.md
     */
    
    contract ERC20CoreBase {
    
        // string public name;
        // string public symbol;
        // uint8 public decimals;
    
    
        mapping (address => uint) internal _balanceOf;
        uint internal _totalSupply; 
    
        event Transfer(
            address indexed from,
            address indexed to,
            uint256 value
        );
    
    
        /**
        * @dev Total number of tokens in existence
        */
    
        function totalSupply() public view returns(uint) {
            return _totalSupply;
        }
    
        /**
        * @dev Gets the balance of the specified address.
        * @param owner The address to query the balance of.
        * @return An uint256 representing the amount owned by the passed address.
        */
    
        function balanceOf(address owner) public view returns(uint) {
            return _balanceOf[owner];
        }
    
    
    
        /**
        * @dev Transfer token for a specified addresses
        * @param from The address to transfer from.
        * @param to The address to transfer to.
        * @param value The amount to be transferred.
        */
    
        function _transfer(address from, address to, uint256 value) internal {
            _checkRequireERC20(to, value, true, _balanceOf[from]);
    
            _balanceOf[from] -= value;
            _balanceOf[to] += value;
            emit Transfer(from, to, value);
        }
    
    
        /**
        * @dev Internal function that mints an amount of the token and assigns it to
        * an account. This encapsulates the modification of balances such that the
        * proper events are emitted.
        * @param account The account that will receive the created tokens.
        * @param value The amount that will be created.
        */
    
        function _mint(address account, uint256 value) internal {
            _checkRequireERC20(account, value, false, 0);
            _totalSupply += value;
            _balanceOf[account] += value;
            emit Transfer(address(0), account, value);
        }
    
        /**
        * @dev Internal function that burns an amount of the token of a given
        * account.
        * @param account The account whose tokens will be burnt.
        * @param value The amount that will be burnt.
        */
    
        function _burn(address account, uint256 value) internal {
            _checkRequireERC20(account, value, true, _balanceOf[account]);
    
            _totalSupply -= value;
            _balanceOf[account] -= value;
            emit Transfer(account, address(0), value);
        }
    
    
        function _checkRequireERC20(address addr, uint value, bool checkMax, uint max) internal pure {
            require(addr != address(0), "Empty address");
            require(value > 0, "Empty value");
            if (checkMax) {
                require(value <= max, "Out of value");
            }
        }
    
    }
    
    
    contract ERC20 is ERC20CoreBase {
        mapping (address => mapping (address => uint256)) private _allowed;
    
    
        event Approval(
            address indexed owner,
            address indexed spender,
            uint256 value
        ); 
    
    
    	constructor(address to, uint value) public {
    		_mint(to, value);
    	}
    
        /**
        * @dev Function to check the amount of tokens that an owner allowed to a spender.
        * @param owner address The address which owns the funds.
        * @param spender address The address which will spend the funds.
        * @return A uint256 specifying the amount of tokens still available for the spender.
        */
        
        function allowance(address owner, address spender) public view returns(uint) {
            return _allowed[owner][spender];
        }
    
        /**
        * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
        * Beware that changing an allowance with this method brings the risk that someone may use both the old
        * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
        * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
        * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
        * @param spender The address which will spend the funds.
        * @param value The amount of tokens to be spent.
        */
    
        function approve(address spender, uint256 value) public {
            _checkRequireERC20(spender, value, true, _balanceOf[msg.sender]);
    
            _allowed[msg.sender][spender] = value;
            emit Approval(msg.sender, spender, value);
        }
    
        /**
        * @dev Transfer tokens from one address to another
        * @param from address The address which you want to send tokens from
        * @param to address The address which you want to transfer to
        * @param value uint256 the amount of tokens to be transferred
        */
    
        function transferFrom(address from, address to, uint256 value) public {
            _checkRequireERC20(to, value, true, _allowed[from][msg.sender]);
    
            _allowed[from][msg.sender] -= value;
            _transfer(from, to, value);
        }
    
    
    
    
    
    
     
        /**
        * @dev Transfer token for a specified address
        * @param to The address to transfer to.
        * @param value The amount to be transferred.
        */
    
        function transfer(address to, uint256 value) public {
            _transfer(msg.sender, to, value);
        }
    }
    
    
    contract LineAxis is Owned, ERC20 {
    	string public name;
    	string public symbol;
    	uint public decimals;
    	bool public frozen;
    
    
    	/**
    	* Logged when token transfers were frozen/unfrozen.
    	*/
    	event Freeze ();
    	event Unfreeze ();
    	
        modifier onlyUnfreeze() {
            require(!frozen, "Action temporarily paused");
            _;
        }
    
    	constructor(string _name, string _symbol, uint _decimals, uint _total, bool _frozen) public ERC20(msg.sender, _total) {
    		name = _name;
    		symbol = _symbol;
    		decimals = _decimals;
    		frozen = _frozen;
    	}
    
    	function mint(address to, uint value) public onlyOwner {
    		_mint(to, value);
    	}
    
    
    
    
    
    	function freezeTransfers () public onlyOwner {
    		if (!frozen) {
    			frozen = true;
    			emit Freeze();
    		}
    	}
    
    	/**
    	* Unfreeze token transfers.
    	* May only be called by smart contract owner.
    	*/
    	function unfreezeTransfers () public onlyOwner {
    		if (frozen) {
    			frozen = false;
    			emit Unfreeze();
    		}
    	}
    
    	function transfer(address to, uint value) public onlyUnfreeze {
    		super.transfer(to, value);
    	}
    
    
    	function transferFrom(address from, address to, uint value) public onlyUnfreeze {
    		super.transferFrom(from, to, value);
    	}
    }